Rumus dalam Excel

Gambaran umum rumus dalam Excel

Terapkan Ke: Excel untuk Office 365 Excel 2016 Excel 2013 Excel 2010 Excel 2007

Jika baru menggunakan Excel, Anda akan segera menyadari bahwa Excel bukanlah sekadar kisi untuk memasukkan angka dalam kolom atau baris saja. Ya, Excel tak hanya dapat digunakan untuk menemukan total atas kolom atau baris berisi angka, namun juga dapat digunakan untuk menghitung pembayaran hipotek, memecahkan permasalahan matematika dan teknik, atau menemukan pemecahan masalah terbaik berdasarkan jumlah variabel yang dimasukkan.

Excel melakukannya menggunakan rumus dalam sel. Rumus melakukan penghitungan atau tindakan lainnya pada data dalam lembar kerja. Rumus selalu dimulai dengan tanda sama dengan (=), yang dapat diikuti dengan angka, operator matematika (seperti + atau - untuk penambahan atau pengurangan), dan fungsi Excel bawaan untuk mengoptimalkan rumus.

Misalnya, rumus berikut mengalikan 2 dengan 3 lalu menambahkan 5 ke hasil perkalian tersebut sehingga menghasilkan jawaban, 11.

=2*3+5

Ini ada beberapa contoh tambahan yang bisa Anda masukkan dalam lembar kerja.

• =A1+A2+A3    Menambahkan nilai di sel A1, A2, dan A3.
• =SUM(A1:A10)    Menggunakan fungsi SUM untuk mengembalikan jumlah nilai dalam A1 hingga A10.
• =TODAY()    Mengembalikan tanggal saat ini.
• =UPPER("halo")     Mengonversi teks "halo" menjadi "HALO" dengan menggunakan fungsi UPPER.
• =IF(A1>0)    Menggunakan fungsi IF untuk menguji sel A1 guna menentukan jika sel berisi nilai lebih besar dari 0.

Bagian dari rumus Excel

Rumus juga dapat memuat salah satu atau semua hal berikut: fungsi, referensi, operator, dan konstanta.

Bagian-bagian rumus   

1. Fungsi: Fungsi PI() mengembalikan nilai pi: 3,142...

2. Referensi: A2 mengembalikan nilai di sel A2.

3. Konstanta: Nilai angka atau teks yang dimasukkan langsung ke dalam rumus, seperti 2.

4. Operator: Operator ^ (sisipan) memangkatkan angka, dan operator * (tanda bintang) mengalikan angka.

Menggunakan konstanta dalam rumus Excel

Konstanta adalah nilai yang tidak dihitung; nilainya selalu sama. Sebagai contoh, tanggal 9/10/2008, angka 210, dan teks "Pendapatan per Kuartal" adalah konstanta. Suatu ekspresi atau nilai yang dihasilkan dari ekspresi bukanlah konstanta. Jika menggunakan konstanta dalam rumus dan bukan referensi untuk sel (misalnya, =30+70+110), hasil hanya akan berubah jika rumus diubah. Secara umum, sebaiknya letakkan konstanta dalam sel individu agar mudah diubah saat diperlukan, lalu referensikan sel tersebut dalam rumus.

Menggunakan operator perhitungan dalam rumus Excel

Operator menentukan tipe penghitungan yang ingin Anda lakukan pada elemen suatu rumus. Excel mengikuti aturan matematika umum untuk penghitungan, yaitu Tanda Kurung (Parentheses), Eksponen (Exponents), Perkalian dan Pembagian (Multiplication and Division), serta Penambahan dan Pengurangan (Addition and Subtraction), atau disingkat PEMDAS (Please Excuse My Dear Aunt Sally (Tolong Maafkan Bibi Sally Saya)). Menggunakan tanda kurung memungkinkan Anda mengubah urutan penghitungan tersebut.

Tipe operator. Ada empat tipe operator penghitungan yang berbeda: aritmetika, perbandingan, perangkaian teks, dan referensi.

• Operator aritmetika
  Untuk melakukan operasi matematika dasar, seperti penambahan, pengurangan, perkalian, atau pembagian; menggabungkan angka; dan menghasilkan nilai numerik, gunakan operator aritmetika berikut ini.

  Operator aritmetika	Arti	Contoh
  + (tanda plus)	Penambahan	=3+3
  - (tanda minus)	Pengurangan  Negasi	=3–3 =-3
  * (tanda bintang)	Perkalian	=3*3
  / (garis miring)	Pembagian	=3/3
  % (tanda persen)	Persen	30%
  ^ (tanda sisipan)	Eksponensial	=3^3

• Operator perbandingan
  Anda bisa membandingkan dua nilai dengan operator berikut ini. Saat dua nilai dibandingkan dengan menggunakan operator ini, hasilnya adalah nilai logika—TRUE atau FALSE.

  Operator perbandingan	Arti	Contoh
  = (tanda sama dengan)	Sama dengan	=A1=B1
  > (tanda lebih besar dari)	Lebih besar dari	=A1>B1
  > (tanda lebih kecil dari)	Kurang dari	=A1<B1
  >= (tanda lebih besar dari atau sama dengan)	Lebih besar dari atau sama dengan	=A1>=B1
  <= (tanda lebih kecil dari atau sama dengan)	Lebih kecil atau sama dengan	=A1<=B1
  <> (tanda tidak sama dengan)	Tidak sama dengan	=A1<>B1

• Operator perangkaian teks
  Gunakan lambang dan (&) untuk menggabungkan(gabungan) satu atau beberapa string teks untuk menghasilkan sebuah teks tunggal.

  Operator teks	Arti	Contoh
  & (dan)	Menghubungkan, atau menggabungkan, dua nilai untuk menghasilkan satu nilai teks yang berkelanjutan	="North"&"wind" menghasilkan "Northwind". Saat A1 berisi "Nama belakang" dan B1 berisi "Nama depan", =A1&", "&B1 menghasilkan "Nama belakang, Nama depan".

• Operator referensi
  Menggabungkan rentang sel untuk perhitungan dengan operator berikut ini.

  Operator referensi	Arti	Contoh
  : (titik dua)	Operator rentang, yang menghasilkan satu referensi untuk semua sel antara dua referensi, termasuk kedua referensi.	B5:B15
  , (koma)	Operator gabungan, yang menggabungkan beberapa referensi menjadi satu referensi	=SUM(B5:B15,D5:D15)
  (spasi)	Operator irisan, yang menghasilkan satu referensi ke sel yang umumnya untuk dua referensi.	B7:D7 C6:C8

Atas Halaman

Urutan Excel dalam melakukan operasi dalam rumus

Dalam beberapa kasus, urutan perhitungan yang dilakukan bisa mempengaruhi nilai yang dihasilkan rumus, jadi sangat penting untuk memahami bagaimana cara menentukan urutan dan bagaimana Anda bisa mengubah urutan untuk mendapatkan hasil yang diinginkan.

• Urutan penghitungan
  Rumus menghitung nilai dalam susunan spesifik. Rumus di Excel selalu dimulai dengan tanda sama dengan (=). Excel menganggap karakter setelah tanda sama dengan sebagai rumus. Tanda sama dengan berikut ini adalah elemen untuk dihitung (operand), seperti konstanta atau referensi sel. Ini dipisahkan oleh operator perhitungan. Excel menghitung rumus dari kiri ke kanan, sesuai dengan susunan tertentu untuk setiap operator dalam rumus tersebut.
• Operator yang didahulukan dalam rumus Excel
  Jika Anda menggabungkan beberapa operator dalam satu rumus, Excel menjalankan operasi dengan susunan yang diperlihatkan dalam tabel berikut ini. Jika rumus berisi operator dengan susunan yang sama—misalnya, jika rumus berisi operator perkalian dan pembagian—Excel mengevaluasi operator dari kiri ke kanan.

  Operator	Deskripsi
  : (titik dua) (spasi tunggal) , (koma)	Operator referensi
  –	Negasi (seperti –1)
  %	Persen
  ^	Perpangkatan
  * dan /	Perkalian dan pembagian
  + dan –	Penambahan dan pengurangan
  &	Menyambungkan dua string teks (penggabungan)
  = < > <= >= <>	Perbandingan

• Menggunakan tanda kurung dalam rumus Excel
  Untuk mengubah susunan evaluasi, bagian rumus yang dimasukkan dalam kurung harus dihitung terlebih dahulu. Misalnya, rumus berikut ini menghasilkan 11 karena Excel melakukan perkalian sebelum penambahan. Rumus tersebut mengalikan 2 dengan 3 lalu menambahkan 5 ke hasil tersebut.
  =5+2*3
  Sebaliknya, jika Anda menggunakan tanda kurung untuk mengubah sintaks, Excel menjumlahkan 5 dan 2, lalu mengalikan hasilnya dengan 3 untuk menghasilkan 21.
  =(5+2)*3
  Dalam contoh berikut ini, tanda kurung yang menampung bagian pertama rumus memaksa Excel untuk menghitung B4+25 terlebih dahulu lalu membagi hasilnya dengan menjumlahkan nilai dalam sel D5, E5, dan F5.
  =(B4+25)/SUM(D5:F5)
  Atas Halaman

Menggunakan fungsi dan fungsi yang ditumpuk dalam rumus Excel

Fungsi adalah rumus yang telah ditetapkan sebelumnya, menjalankan perhitungan menggunakan nilai tertentu yang disebut argumen, dalam struktur atau susunan tertentu. Fungsi dapat digunakan untuk menjalankan penghitungan sederhana maupun kompleks. Anda dapat menemukan semua fungsi Excel pada tab Rumus di Pita:

• Sintaks fungsi Excel
  Contoh fungsi ROUND yang membulatkan angka dalam sel A10 berikut menggambarkan sintaks fungsi.
  
  1. Struktur. Struktur fungsi dimulai dengan tanda sama dengan (=), diikuti dengan nama fungsi, tanda kurung buka, argumen untuk fungsi yang dipisahkan oleh koma, dan tanda kurung tutup.
  2. Nama fungsi. Untuk daftar fungsi yang tersedia, klik sel dan tekan SHIFT+F3, yang akan meluncurkan dialog Sisipkan Fungsi.
  
  3. Argumen. Argumen dapat berupa angka, teks, nilai logika seperti TRUE atau FALSE, larik, nilai yang salah seperti #N/A, atau referensi sel. Argumen yang Anda tentukan harus menghasilkan nilai yang valid untuk argumen tersebut. Argumen juga dapat berupa konstanta, rumus, atau fungsi lainnya.
  4. Tipsalat argumen. Tipsalat dengan sintaks dan argumen akan muncul saat Anda mengetik fungsi. Misalnya, ketik =ROUND( dan tipsalat akan muncul. Tipsalat hanya muncul untuk fungsi bawaan.
  Catatan: Anda tidak perlu mengetik fungsi dalam huruf besar, seperti =ROUND, karena Excel akan secara otomatis menulis nama fungsi dalam huruf besar setelah menekan enter. Jika Anda salah mengeja nama fungsi, seperti =SUME(A1:A10) bukan = SUM(A1:A10), Excel akan mengembalikan kesalahan #NAME?.
• Memasukkan fungsi Excel
  Ketika membuat rumus yang berisi fungsi, Anda dapat menggunakan kotak dialog Sisipkan Fungsi untuk membantu memasukkan fungsi lembar kerja. Saat memilih fungsi dari dialog Sisipkan Fungsi, Excel akan meluncurkan panduan fungsi yang menampilkan nama fungsi, setiap argumennya, deskripsi fungsi dan setiap argumen, hasil fungsi saat ini, dan hasil keseluruhan rumus saat ini.
  
  Untuk memudahkan Anda membuat dan mengedit rumus serta mengurangi kesalahan pengetikan dan sintaks, gunakan Pelengkap Otomatis Rumus. Setelah mengetik = (tanda sama dengan) dan huruf awal fungsi, Excel akan menampilkan daftar menurun yang dinamis berisi fungsi, argumen, dan nama yang sesuai dengan huruf tersebut. Anda kemudian dapat memilih rumus dari daftar menurun, dan Excel akan memasukkannya.
  
• Menumpuk fungsi Excel
  Dalam kasus tertentu, Anda mungkin perlu menggunakan fungsi sebagai salah satu argumen fungsi lain. Rumus berikut ini misalnya, menggunakan fungsi AVERAGE yang bertumpuk dan membandingkan hasil dengan nilai 50.
  
  1. Fungsi AVERAGE dan SUM ditumpuk di dalam fungsi IF.
  Hasil yang valid    Ketika fungsi yang ditumpuk digunakan sebagai argumen, fungsi yang ditumpuk harus menghasilkan nilai tipe yang sama dengan yang digunakan argumen. Misalnya, jika argumen menghasilkan nilai TRUE atau FALSE, fungsi yang ditumpuk harus menghasilkan nilai TRUE atau FALSE. Jika fungsi tidak menampilkan nilai yang sama, Excel menampilkan nilai kesalahan #VALUE!.
  Batas tingkat tumpukan    Rumus bisa memuat hingga tujuh tingkat fungsi yang ditumpuk. Ketika satu fungsi (kami akan menyebut ini fungsi B) digunakan sebagai argumen dalam fungsi lain (kami akan menyebut ini fungsi A), fungsi B bertindak sebagai fungsi tingkat kedua. Sebagai contoh, fungsi AVERAGE dan fungsi SUM adalah fungsi tingkat kedua jika digunakan sebagai argumen dari fungsi IF. Fungsi yang ditumpuk di dalam fungsi AVERAGE bertumpuk adalah fungsi level tiga, dan seterusnya.
  Atas Halaman

Menggunakan referensi dalam rumus Excel

Referensi mengidentifikasi sel atau rentang sel di lembar kerja, dan memberitahu Excel tempat untuk mencari nilai atau data yang ingin Anda gunakan dalam rumus. Gunakan referensi untuk menggunakan data yang berada di bagian lain lembar kerja dalam satu rumus atau gunakan nilai dari satu sel dalam beberapa rumus. Anda juga bisa mengacu ke sel pada lembar lainnya dalam buku kerja yang sama, dan ke buku kerja lainnya. Referensi ke sel dalam buku kerja lainnya disebut tautan atau referensi eksternal.

• Gaya referensi A1
  Secara default, Excel menggunakan gaya referensi A1, yang mengacu pada kolom dengan huruf (A hingga XFD, dengan total kolom 16.384) dan mengacu pada baris dengan angka (1 hingga 1.048.576). Huruf dan angka ini disebut judul baris dan kolom. Untuk mengacu pada sel, masukkan huruf kolom yang diikuti dengan nomor baris. Sebagai contoh, B2 mengacu pada sel di titik temu antara kolom B dan baris 2.

  Untuk merujuk ke	Gunakan
  Sel dalam kolom A dan baris 10	A10
  Rentang sel dalam kolom A dan baris 10 hingga 20	A10:A20
  Rentang sel dalam baris 15 dan kolom B hingga E	B15:E15
  Semua sel dalam baris 5	5:5
  Semua sel dalam baris 5 hingga 10	5:10
  Semua sel dalam kolom H	H:H
  Semua sel dalam kolom H hingga J	H:J
  Rentang sel dalam kolom A hingga E dan baris 10 hingga 20	A10:E20

• Membuat referensi ke sel atau rentang sel di lembar kerja lain dalam buku kerja yang sama
  Dalam contoh berikut, fungsi AVERAGE menghitung nilai rata-rata untuk rentang B1:B10 pada lembar kerja yang bernama Pemasaran dalam buku kerja yang sama.
  
  1. Merujuk ke lembar kerja bernama Marketing
  2. Mengacu pada rentang sel dari B1 ke B10
  3. Tanda seru (!) Memisahkan referensi lembar kerja dari referensi rentang sel
  Catatan: Jika lembar kerja yang direferensikan memiliki spasi atau angka di dalamnya, Anda perlu menambahkan apostrof (') sebelum dan setelah nama lembar kerja, seperti ='123'!A1 atau ='Pendapatan Januari'!A1.
• Perbedaan antara referensi absolut, relatif, dan campuran
  1. Referensi relatif    Referensi sel relatif dalam rumus, seperti A1, didasarkan pada posisi relatif dari sel yang berisi rumus dan sel yang diajukan oleh referensi. Jika posisi sel yang berisi rumus berubah, referensi berubah. Jika Anda menyalin atau mengisi rumus di seluruh baris atau kolom, referensi akan menyesuaikan secara otomatis. Secara default, rumus baru menggunakan referensi relatif. Misalnya, jika Anda menyalin atau mengisi referensi relatif dalam sel B2 ke sel B3, referensi disesuaikan secara otomatis dari =A1 ke =A2.
     Rumus salinan dengan referensi relatif   
     
  2. Referensi absolut    Referensi sel absolut dalam rumus, seperti $A$1, selalu mengacu pada sel dalam lokasi tertentu. Jika posisi sel yang berisi rumus berubah, referensi absolut tetap sama. Jika Anda menyalin atau mengisi rumus di seluruh baris atau kolom, referensi absolut tidak disesuaikan. Secara default, rumus baru menggunakan referensi relatif , jadi Anda mungkin harus mengubahnya menjadi referensi absolut. Misalnya, jika menyalin atau mengisi referensi absolut dalam sel B2 ke cell B3, referensi tetap sama dalam kedua sel: =$A$1.
     Rumus salinan dengan referensi absolut   
     
  3. Referensi campuran    Referensi campuran memiliki kolom absolut dan baris relatif, atau baris absolut dan kolom relatif. Kolom referensi absolut berupa $A1, $B1, dan seterusnya. Baris referensi absolut berupa A$1, B$1, dan seterusnya. Jika posisi sel yang berisi rumus berubah, referensi relatif juga berubah, dan referensi absolut tidak berubah. Jika Anda menyalin atau mengisi rumus di seluruh baris atau kolom, referensi relatif disesuaikan secara otomatis, dan referensi absolut tidak disesuaikan secara otomatis. Contohnya, jika menyalin atau mengisi referensi campuran dari sel A2 ke B3, referensi disesuaikan dari =A$1 ke =B$1.
     Rumus salinan dengan referensi campuran   
     
• Gaya referensi 3-D
  Mereferensikan beberapa lembar kerja dengan nyaman    Jika Anda ingin menganalisa data dalam sel yang sama atau rentang sel di beberapa lembar kerja di dalam buku kerja, gunakan referensi 3-D. Referensi 3-D termasuk referensi sel atau rentang, didahului dengan nama lembar kerja. Excel menggunakan semua lembar kerja yang disimpan di antara nama awal dan nama akhir referensi. Misalnya, =SUM(Sheet2:Sheet13!B5) menambahkan semua nilai yang terdapat di sel B5 pada semua lembar kerja di antara dan termasuk Lembar 2 dan Lembar 13.
  • Anda bisa menggunakan referensi 3-D untuk merujuk ke sel di lembar lain, untuk menentukan nama, dan untuk membuat rumus dengan menggunakan fungsi berikut ini: SUM, AVERAGE, AVERAGEA, COUNT, COUNTA, MAX, MAXA, MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S, VARA, dan VARPA.
  • Referensi 3-D tidak bisa digunakan dalam rumus array.
  • Referensi 3-D tidak bisa digunakan dengan operator irisan (satu spasi) atau dalam rumus yang menggunakan irisan implisit.
  Apa yang terjadi ketika Anda memindahkan, menyalin, menyisipkan, atau menghapus lembar kerja    Contoh berikut ini menjelaskan apa yang terjadi ketika Anda memindahkan, menyalin, menyisipkan, atau menghapus lembar kerja yang termasuk dalam referensi 3-D. Contoh yang menggunakan rumus =SUM(Lembar2:Lembar6!A2:A5) untuk menambahkan sel A2 hingga A5 pada lembar kerja 2 hingga 6.
  • Sisipkan atau salin     Jika Anda menyisipkan atau menyalin lembar kerja antara Lembar2 dan Lembar6 (titik akhir dalam contoh ini), Excel akan memasukkan semua nilai dalam sel A2 sampai A5 dari lembar kerja yang ditambahkan dalam perhitungan.
  • Hapus     Jika Anda menghapus lembar antara Lembar2 dan Lembar6, Excel akan menghapus nilainya dari perhitungan.
  • Pindahkan     Jika Anda memindahkan lembar dari antara Lembar2 dan Lembar6 ke lokasi di luar rentang lembar yang dirujuk, Excel akan menghapus nilainya dari perhitungan.
  • Pindahkan titik akhir    Jika Anda memindahkan Lembar2 atau Lembar6 ke lokasi lain di buku kerja yang sama, Excel menyesuaikan perhitungan untuk mengakomodasi rentang baru lembar antara keduanya.
  • Hapus titik akhir    Jika Anda menghapus Lembar2 atau Lembar6, Excel menyesuaikan perhitungan untuk mengakomodasi rentang baru lembar antara keduanya.
• Gaya referensi R1C1
  Anda juga bisa menggunakan gaya referensi yang memberi nomor baris dan kolom pada lembar kerja. Gaya referensi R1C1 berguna untuk komputerisasi posisi baris dan kolom di makro. Dalam gaya R1C1, Excel menunjukkan lokasi sel dengan "R" diikuti oleh jumlah baris dan "C" diikuti oleh jumlah kolom.

  Referensi	Arti
  R[-2]C	referensi relatif ke sel dua baris ke atas dan dalam kolom yang sama
  R[2]C[2]	Referensi relatif ke sel dua baris ke bawah dan dua kolom ke kanan
  R2C2	Referensi absolut ke sel dalam baris kedua dan dalam kolom kedua
  R[-1]	Referensi relatif ke seluruh baris di atas sel aktif
  R	Referensi absolut ke baris saat ini

  Ketika Anda merekam makro, Excel merekam beberapa perintah dengan menggunakan gaya referensi R1C1. Misalnya, jika Anda merekam perintah, seperti mengklik tombol AutoSum untuk menyisipkan rumus yang menambahkan rentang sel, Excel merekam rumus dengan menggunakan gaya referensi R1C1, bukan gaya referensi A1.
  Anda bisa mengaktifkan atau menonaktifkan gaya referensi R1C1 dengan mencentang atau mengosongkan kotak centang gaya referensi R1C1pada bagian Bekerja dengan rumus dalam kategori Rumus di kotak dialog Opsi. Untuk menampilkan kotak dialog ini, klik tab File.
  Atas Halaman

Menggunakan nama dalam rumus Excel

Anda bisa membuat nama yang ditentukan untuk mewakili sel, rentang sel, rumus, konstanta, atau tabel Excel. Nama adalah singkatan bermakna yang memudahkan untuk memahami tujuan suatu referensi sel, konstanta, rumus, atau tabel, yang mana masing-masing mungkin akan sulit untuk dipahami secara sekilas. Informasi berikut ini memperlihatkan contoh-contoh umum nama dan cara menggunakannya dalam rumus yang bisa meningkatkan kejelasan dan membuat rumus lebih mudah untuk dipahami.

Contoh 1

Tipe contoh	Contoh, menggunakan rentang dan bukan nama	Contoh, menggunakan nama
Referensi	=SUM(A16:A20)	=SUM(Penjualan)
Konstanta	=PRODUCT(A12,9.5%)	=PRODUCT(Harga,TarifPajak)
Rumus	=TEXT(VLOOKUP(MAX(A16,A20),A16:B20,2,FALSE),"d/mm/yyyy")	=TEXT(VLOOKUP(MAX(Penjualan),InfoPenjualan,2,FALSE),"d/mm/yyyy")
Tabel	A22:B25	=PRODUCT(Harga,Tabel1[@Tarif Pajak)

Contoh 2

Salin contoh data di dalam tabel berikut ini dan tempel ke dalam sel A1 lembar kerja Excel yang baru. Agar rumus memperlihatkan hasil, pilih datanya, tekan F2, lalu tekan Enter. Jika perlu, Anda bisa menyesuaikan lebar kolom untuk melihat semua data.

Catatan:  Dalam rumus di kolom C dan D, nama "Penjualan" yang ditentukan menggantikan referensi pada (rentang) A9:A13 dan nama "InfoPenjualan" menggantikan rentang A9:B13. Jika tidak membuat nama ini dalam buku kerja percobaan Anda, rumus di D2:D3 akan mengembalikan kesalahan #NAME?.

Tipe contoh	Contoh, tidak menggunakan nama	Contoh, menggunakan nama	Rumus dan hasilnya, menggunakan nama
Referensi	'=SUM(A9:A13)	‘=SUM(Penjualan)	=SUM(Penjualan)
Rumus	'=TEXT(VLOOKUP(MAX(A9:13),A9:B13,2,FALSE),"d/mm/yyyy")	'=TEXT(VLOOKUP(MAX(Penjualan),InfoPenjualan,2,FALSE),"d/mm/yyyy")	=TEXT(VLOOKUP(MAX(Penjualan),InfoPenjualan,2,FALSE),"d/mm/yyyy")
Harga
$995
Penjualan	Tanggal Penjualan
$249	17/3/2011
$399	2/4/2011
$643	23/4/2011
$275	30/4/2011
$447	4/5/2011

• Tipe nama
  Terdapat beberapa tipe nama yang bisa Anda buat dan gunakan.
  • Nama yang ditentukan    Nama mewakili nilai sel, rentang sel, rumus, atau konstanta. Buat sendiri nama yang ditentukan. Juga, Excel kadang-kadang membuat nama yang ditentukan untuk Anda, seperti ketika mengatur area cetak.
  • Nama tabel    Nama untuk tabel Excel, yang merupakan koleksi data mengenai subjek tertentu yang disimpan dalam rekaman (baris) dan bidang (kolom). Excel membuat nama tabel default Excel Tabel1, Tabel2, dan seterusnya, setiap kali menyisipkan tabel Excel, namun Anda bisa mengubah nama ini untuk membuatnya lebih bermakna.
    Untuk informasi selengkapnya tentang tabel Excel, lihat Menggunakan referensi terstruktur dengan tabel Excel.
• Membuat dan memasukkan nama
  Anda membuat nama dengan menggunakan:
  • Kotak nama pada bilah rumus    Paling tepat digunakan untuk membuat nama tingkat buku kerja untuk rentang terpilih.
  • Buat nama dari pilihan    Anda bisa membuat nama dengan nyaman dari label baris dan kolom yang telah ada dengan menggunakan pilihan sel dalam buku kerja.
  • Kotak dialog Nama Baru   Cara terbaik apabila Anda menginginkan fleksibilitas dalam membuat nama, misalnya menentukan lingkup tingkat lembar kerja atau membuat komentar nama.
  Catatan: Secara default, nama menggunakan referensi sel absolut.
  Anda bisa memasukkan nama dengan:
  • Mengetikkan     Mengetikkan nama, misalnya, sebagai argumen untuk rumus.
  • Menggunakan Rumus Pelengkap Otomatis    Gunakan daftar menurun Rumus LengkapiOtomatis, tempat nama yang valid secara otomatis dicantumkan untuk Anda.
  • Memilih dari perintah Gunakan dalam Rumus    Pilih nama yang ditentukan dari daftar yang tersedia di perintah Gunakan dalan Rumus dalam grup Nama yang Ditentukan pada tab Rumus.

Untuk informasi selengkapnya, lihat Menjelaskan dan menggunakan nama dalam rumus.

Atas Halaman

Menggunakan rumus array dan konstanta array di Excel

Rumus array bisa menjalankan beberapa perhitungan dan menghasilkan satu hasil atau beberapa hasil. Rumus array dijalankan pada dua atau beberapa set nilai yang dikenal sebagai argumen larik. Setiap argumen larik harus memiliki jumlah baris dan kolom yang sama. Membuat rumus array sama dengan cara membuat rumus yang lain, bedanya tekan CTRL+SHIFT+ENTER untuk memasukkan rumus. Beberapa fungsi bawaan merupakan rumus array, dan harus dimasukkan sebagai larik untuk mendapatkan hasil yang tepat.

Konstanta array bisa digunakan dalam tempat yang direferensikan ketika Anda tidak ingin memasukkan setiap nilai konstanta dalam sel yang terpisah pada lembar kerja.

Menggunakan rumus larik untuk menghitung satu atau beberapa hasil

Catatan: Ketika memasukkan rumus array, Excel akan secara otomatis menyisipkan rumus di antara { } (kurung kurawal). Jika mencoba memasukkan tanda kurung kurawal sendiri, Excel akan menampilkan rumus Anda sebagai teks.

• Rumus larik yang menghasilkan satu hasil    Tipe rumus larik ini dapat menyederhanakan model lembar kerja dengan mengganti beberapa rumus yang berbeda dengan satu rumus larik.
  Contohnya, rumus berikut menghitung nilai total larik harga dan jumlah saham, tanpa menggunakan baris sel untuk menghitung dan menampilkan nilai individual untuk setiap saham.
  
  Ketika Anda memasukkan ={SUM(B2:D2*B3:D3)} sebagai rumus array, rumus mengalikan Jumlah dan Harga untuk setiap saham, lalu menambahkan hasil perhitungan tersebut sekaligus.
• Rumus larik yang menghasilkan beberapa hasil    Beberapa fungsi lembar kerja menghasilkan nilai larik, atau membutuhkan nilai larik sebagai argumen. Untuk menghitung beberapa hasil dengan rumus larik, Anda harus memasukkan larik ke dalam rentang sel yang memiliki jumlah baris dan kolom yang sama dengan argumen larik.
  Sebagai contoh, terdapat rangkaian tiga angka penjualan (dalam kolom B) untuk rangkaian tiga bulan (dalam kolom A), fungsi TRENDmenentukan nilai langsung untuk angka penjualan. Untuk menampilkan semua hasil rumus, masukkan ke dalam tiga sel di kolom C (C1:C3).
  
  Saat Anda memasukkan rumus =TREND(B1:B3,A1:A3) sebagai rumus array, rumus menghasilkan tiga hasil terpisah (22196, 17079, dan 11962), didasarkan pada tiga angka penjualan dan tiga bulan.

Menggunakan konstanta larik

Dalam rumus biasa, Anda bisa memasukkan referensi ke sel yang berisi nilai, atau nilai itu sendiri, juga disebut konstanta. Begitu juga, dalam rumus array Anda bisa memasukkan referensi ke array, atau memasukkan nilai yang dimuat dalam sel, juga disebut konstanta array. Rumus menerima konstanta dalam cara yang sama yang dilakukan rumus non array, Anda harus memasukkan konstanta array dalam format tertentu.

Konstanta larik bisa berisi angka, teks, nilai logika seperti TRUE atau FALSE, atau nilai kesalahan seperti #N/A. Tipe-tipe nilai yang berbeda bisa berada di konstanta LARIK yang berbeda — misalnya, {1,3,4;TRUE,FALSE,TRUE}. Jumlah konstanta larik bisa berupa bilangan bulat, desimal, atau format ilmiah. Teks harus dimasukkan dalam tanda petik ganda — misalnya, “Selasa”.

Konstanta larik tidak boleh berisi referensi sel, kolom atau baris yang panjangnya tidak sama, rumus, atau karakter khusus $ (tanda dolar), tanda kurung atau % (tanda persen).

Ketika memformat konstanta larik, pastikan Anda:

• Memasukkannya dalam kurung kurawal ( { } ).
• Memisahkan nilai dalam kolom yang berbeda dengan menggunakan koma (,). Misalnya, untuk mewakili nilai 10, 20, 30, dan 40, masukkan {10,20,30,40}. Konstanta larik ini dikenal sebagai larik 1 kali 4 dan sama dengan referensi 1-baris-kali-4-kolom.
• Memisahkan nilai dalam baris yang berbeda dengan menggunakan titik koma(;). Misalnya, untuk mewakili nilai 10, 20, 30, dan 40 dalam satu baris dan 50, 60, 70, dan 80 dalam baris tepat di bawahnya, Anda memasukkan konstanta 2 kali 4: {10,20,30,40;50,60,70,80}.

Atas Halaman

Menghapus rumus

Ketika Anda menghapus rumus, nilai rumus yang dihasilkan juga dihapus. Namun, Anda dapat menghapus rumusnya saja dan membiarkan nilai rumus yang dihasilkan ditampilkan dalam sel.

• Untuk menghapus rumus beserta nilai-nilai yang dihasilkan, lakukan hal berikut:
  1. Pilih sel atau rentang sel yang berisi rumus.
  2. Tekan DELETE.
• Untuk menghapus rumus tanpa menghapus nilai-nilai yang dihasilkan, lakukan hal berikut:
  1. Pilih sel atau rentang sel yang berisi rumus.
     Jika rumus adalah rumus array, pilih rentang sel yang berisi rumus array.
     Cara memilih rentang sel yang berisi rumus larik
     1. Klik sel di rumus array.
     2. Pada tab Beranda, dalam grup Pengeditan, klik Temukan & Pilih, lalu klik Buka.
     3. Klik Spesial.
     4. Klik Array saat ini.
  2. Di tab Beranda, dalam grup Clipboard, klik Salin  .
      
     
     
     Pintasan keyboard    Anda juga dapat menekan CTRL+C.
  3. Pada tab Beranda, dalam grup Clipboard, klik panah di bawah Tempel  , lalu klik Tempelkan Nilai.

Atas Halaman

Menghindari kesalahan umum saat membuat rumus

Tabel berikut ini merangkum beberapa kesalahan paling umum yang mungkin Anda lakukan saat memasukkan rumus, dan cara menghindari kesalahan rumus:

Pastikan bahwa Anda…	Informasi selengkapnya
Cocokkan semua kurung buka dan tutup dalam rumus	Semua tanda kurung adalah pasangan yang tak terpisahkan dalam rumus. Ketika Anda membuat rumus, Excel akan menampilkan tanda kurung berwarna saat dimasukkan.
Gunakan tanda titik dua untuk menunjukkan rentang yang Anda masukkan dalam rumus	Titik dua (:) digunakan untuk memisahkan referensi ke sel pertama dan terakhir dalam rentang. Misalnya, A1:A5.
Memasukkan semua argumen yang diperlukan	Fungsi dapat memiliki argumen yang diperlukan dan argumen opsional (ditunjukkan oleh kurung siku dalam sintaks). Semua argumen yang diperlukan harus dimasukkan. Selain itu, pastikan bahwa Anda tidak memasukkan terlalu banyak argumen.
Jangan menumpuk lebih dari 64 fungsi dalam satu rumus	Fungsi bertumpuk dalam rumus dibatasi hingga 64 tingkat.
Kurung nama buku kerja atau lembar kerja dalam tanda kutip tunggal	Saat mengacu pada nilai atau sel di lembar kerja atau buku kerja yang memiliki karakter non-alfabet dalam namanya, nama tersebut harus dikurung dalam tanda kutip tunggal ( ' ).
Menyertakan jalur ke buku kerja eksternal	Referensi eksternal harus berisi nama buku kerja dan jalur ke buku kerja tersebut.
Memasukkan angka tanpa pemformatan	Angka yang Anda masukkan dalam rumus tidak boleh diformat dengan tanda dolar ($) atau pemisah desimal karena tanda koma telah digunakan sebagai pemisah argumen dalam rumus, dan tanda dolar digunakan untuk menandai referensi absolut. Misalnya, jangan memasukkan $1.000, cukup masukkan 1000dalam rumus.

Atas Halaman

Penting: Hasil yang dihitung dari rumus dan beberapa fungsi lembar kerja Excel dapat sedikit berbeda antara Windows PC yang menggunakan arsitektur x86 atau x86-64 dan PC Windows RT yang menggunakan arsitek ARM. Pelajari selengkapnya tentang perbedaan.